; MEMORY LAYOUT
; R = reserved, U = usable
; --------------------------------------------------------------------
; R | 0x000000 - 0x000400: real-mode interrupt vector table
; R | 0x000400 - 0x000500: bios data area
; U | 0x000500 - 0x007c00: stack
; U |   0x007000 - 0x007c00: big stage0 initial stack frame
;   |     0x007000 - 0x007001: boot drive number
;   |     0x007001 - 0x007002: boot drive sectors per track
;   |     0x007002 - 0x007004: boot drive number of heads
; U | 0x007c00 - 0x007e00: boot sector
; U | 0x007e00 - 0x080000: conventional usable memory
; R | 0x080000 - 0x0a0000: extended bios data area (maximum possible size)
; R | 0x0a0000 - 0x0c0000: video memory
; R | 0x0c0000 - 0x0c8000: video bios
; R | 0x0c8000 - 0x0f0000: bios expansiosn
; R | 0x0f0000 - 0x100000: motherboard bios

; BIOS puts our boot sector at 0000:7c00
org 0x7c00
; We're (probably) in real mode
bits 16 

  ; Disable interrupts
  cli

  xor ax, ax

  mov ds, ax
  mov es, ax

  ; We put stack base at 0x7c00 and give ourselves a big stack frame [0x7000,0x7c00) for spilling to.
  ; Stack grows high->low, so we'll grow away from our program text at 0x7c00.
  mov ss, ax
  mov sp, 0x7c00
  mov bp, 0x7000

  ; Segment for VGA (0xb800 * 16 = 0xb8000)
  mov ax, 0xb800
  mov fs, ax

  ; Store boot drive number
  mov [bp], dl

  ; Get drive geometry
  mov di, 0x00
  mov ah, 0x08
  int 0x13
  jc panic
  and cl, 0x3f     ; sectors per track
  mov [bp + 1], cl
  movzx bx, dh
  inc bx           ; number of heads
  mov [bp + 2], bx

  ; Load LBA 1.
  cmp cl, 1  ; division of 1 by nonzero can be done with cmp
  sete al    ; temp = LBA / (sectors per track)
  setne cl   ; sector - 1 = LBA % (sectors per track)
  inc cl
  xor ah, ah ; zero-extend temp
  xor dx, dx ; TODO: explain why this is needed for div
  div bx     ; ah = mod (head), al = div (cylinder)
  
  mov dh, ah ; head
  mov ch, al ; cylinder
             ; we already have sector in cl
  mov ah, 2  ; read disk
  mov al, 1  ; load one sector
  mov bx, 0x7e00
  mov dl, [bp] ; drive number
  int 0x13
  jc panic

  ; head = temp % number of heads
  ; cylinder = temp / number of heads

  ; Set VGA mode
  ; https://mendelson.org/wpdos/videomodes.txt
  mov ax, 0x0003
  int 0x10

  ; mov word fs:[0x0000], 0xc048
  ; mov word fs:[0x0002], 0xc069
  mov al, [0x7e00]
  mov byte fs:[0x0000], al
  mov al, [0x7e01]
  mov byte fs:[0x0002], al
  mov al, [0x7e02]
  mov byte fs:[0x0004], al
  hlt

panic:
  mov ax, 0x0003
  int 0x10
  mov ax, 0xb800
  mov ds, ax
  mov word [0x0000], 0x4f46
  mov word [0x0002], 0x4f41
  mov word [0x0004], 0x4f49
  mov word [0x0006], 0x4f4c
  hlt

  ; TODO: enable A20

  ; TODO: load a second stage

  ; TODO: grab all the info we can from bios interrupts and deliver it to ths OS nicely
  ; e.g. in a fixed memory location

  ; TODO:
  ; - Generate GPT in justfile
  ; - Parse global parition table
  ; - Load second stage from GPT partition with a particular UUID / name like GRUB does
  ;   (it's Hah!IdontNeedEFI in GRUB)
  ;   - https://en.wikipedia.org/wiki/BIOS_boot_partition
  ; - Future work:
  ;   - Boot from UEFI
  ;   - Boot on non-GPT partitioned disk

  ; MBR bootstrap field is 440 bytes long
  %if ($ - $$) > 440
  %error "exceeded mbr bootstrap field size"
  %endif